; Read Battery Clock Data - by BlackWine/Anadune for MayDay Debugger...

ReadClock
	lea	$dc0030,a0
	lea	TOD(pc),a1
	moveq	#-16,d1
	moveq	#-64,d2

; Year
	move.l	-(a0),d0
	eor.b	d2,d0
	move.b	d0,(a1)+
	move.l	-(a0),d0
	eor.b	d2,d0
	move.b	d0,(a1)+

; Month
	move.l	-(a0),d0
	eor.w	d1,d0
	sne	d0
	and.w	#$a,d0
	move.l	-(a0),d3
	eor.w	d1,d3
	add.w	d3,d0
	subq	#1,d0
	lsl.w	#2,d0
	move.l	Months(pc,d0.w),(a1)+	; no *4 mode for 000 compatibility
; Day
	move.b	#'-',(a1)+
	move.l	-(a0),d0
	eor.b	d2,d0
	move.b	d0,(a1)+
	move.l	-(a0),d0
	eor.b	d2,d0
	move.b	d0,(a1)+

	move.b	#' ',(a1)+

; Day of Week
	move.w	$18(a0),d0
	eor	d1,d0
	lsl	#2,d0
	move.l	Days(pc,d0.w),(a1)+

; Time
	move.l	-(a0),d0
	eor.b	d2,d0
	move.b	d0,(a1)+
	move.l	-(a0),d0
	eor.b	d2,d0
	move.b	d0,(a1)+
	move.b	#':',(a1)+

	move.l	-(a0),d0
	eor.b	d2,d0
	move.b	d0,(a1)+
	move.l	-(a0),d0
	eor.b	d2,d0
	move.b	d0,(a1)+
	move.b	#':',(a1)+

	move.l	-(a0),d0
	eor.b	d2,d0
	move.b	d0,(a1)+
	move.l	-(a0),d0
	eor.b	d2,d0
	move.b	d0,(a1)+

	rts

TOD	;dc.b	'Clock Not Found! Oopss'
	dc.b	'xx-xxx-xx xxx xx:xx:xx'

Months	dc.b	'-Jan-Feb-Mar-Apr-May-Jun-Jul-Aug-Sep-Oct-Nov-Dec'
Days	dc.b	'Sun Mon Tue Wed Thu Fri Sat '